The Land of Breakfast and Lunch — 4 of 9

Section 3 - The Land of Unrealized Possibilities

The Hopeful Path is a room. "You are on the hopeful path. Backwards from here is The Land of Breakfast and Lunch. Forward is The Land of Unrealized Possibilities." The Hopeful Path is north of TLoBL.

Hopeypath is in The Hopeful Path. It is scenery. The description of Hopeypath is "It's a simple, foot-trod path that connects The Land of Breakfast and Lunch and The Land of Unrealized Possibilities." Understand "path" as Hopeypath.

TLoUP is a room. "You are in the Land of Unrealized Possibilities. Just being here gives you a sense of all that could be accomplished if enough time, effort, and focus were pointed in a specific direction. There is a sense of both excitement and disappointment here that is almost palpable. The Hopeful Path leads backward towards The Land of Breakfast and Lunch, a place with a much clearer sense of purpose. The Seaside Path leads forward, towards The Land of Unlaunched Vessels." TLoUP is north of the hopeful path.

The printed name of TLoUP is "The Land of Unrealized Possibilities"

[The Toy Box]

There is a toy box in TLoUP. It is an openable closed container. It is fixed in place. The description of the toy box is "It is a large simple wooden toy box stained with a nice hand-painted varnish. It has a hinged lid on top."

The hinged wooden lid is a part of the toy box.

Instead of opening the hinged wooden lid:

try opening the toy box.

Understand "lift [lid]" as opening.

Instead of taking the toy box, say "You could probably lift it, but it's a sturdy wooden box and heavier than anything you want to carry around."

Instead of pushing or pulling the toy box, say "It's a nicely made wooden box, you're just going to scuff it up shoving it around."

There is a wooden block in the toy box. The block is puppy-throwable. The description of the wooden block is "It is a simple block made out of wood. It is an unpainted cube, with very slightly rounded corners. It's the kind of thing you would find at a Montessori school, usually in the company of many of its compatriots. This one is alone."

[Playing with things]

Playing with is an action applying to one visible thing.

Understand "play with [a visible thing]" as playing with.

Instead of playing with a visible thing:

say "You did. You are good at entertaining yourself.".

Instead of playing with Mister Tuxedo:

say "Mister Tuxedo has a preferred way he likes to be played with: throwing something for him to catch.".

Instead of playing with the wooden block:

say "It's just one block. It's possibly the single most boring toy imaginable by itself.".

Instead of playing with the plastic doll:

try bending the plastic doll.

Instead of playing with the lite-brite:

say "You'd need the pegs.".

Instead of playing with the hobby horse:

try riding the hobby horse.

Instead of playing with the coloring book:

try coloring the coloring book.

Instead of playing with the jack-in-the-box:

try opening the jack-in-the-box.

Instead of playing with breasts:

say "C'mon dude.".

There is a skinny naked plastic doll in the toy box. The naked doll is puppy-throwable. The description is "The face of the skinny plastic doll is forever frozen in an expression of bored self-satisfaction. Its long naked arms and legs bend and articulate, but not much. Its breasts are idealized, yet awkwardly shaped, like rounded pyramids. It has nylon synthetic hair that cascades stiffly around its shoulders.". The nylon hair is a part of the doll. The description is "The hair is really tiny tufts of nylon that poke out of holes in the doll's head.". The breasts are a part of the plastic doll. The description is "They are merely designed to fill out a miniature blouse, and look very unnatural unclothed.". Understand "arms/legs/arm/leg/shoulder" as the doll.

Understand "bend [the plastic doll]" as bending. Bending is an action applying to one visible thing.

Instead of bending the plastic doll:

try taking the plastic doll;

say "You twist the doll into a few unlikely positions, as if getting ready to horrify an imaginary younger sister. Then, you are bored and bend her back to her awkwardly stiff standing pose.".

[The jack-in-the-box]

There is a closed jack-in-the-box in the toy box.

Understand "jack/box" or "jack-in-the-box" or "jack in the box" as the closed jack-in-the-box.

The description of the closed jack-in-the-box is "The jack-in-the-box is a brightly painted tin cube, and actually looks to be some sort of antique. It is detailed with flames, and written on the back and front are the words 'diable en boîte'. It has a tightly fitted lid on top, and a small wire and wood hand crank on one side.". The usable hand crank is a part of the closed jack-in-the-box. The description is "A wire hand crank with a small wooden ball as a handle on the end.". The closed tin lid is a part of the closed jack-in-the-box. Wire is a part of the crank. The description is "The crank is a piece of thick wire bent twice." Ball is a part of the crank. The description is "A wooden ball attached to the crank acts as a free-rotating handle for the crank."

Understand "turn [the usable hand crank]" as opening.

Understand "twist [the usable hand crank]" as opening.

Instead of opening the usable hand crank:

try opening the closed jack-in-the-box.

Instead of closing the closed tin lid, say "It's already tightly closed."

Instead of opening the closed tin lid, say "It's tightly closed. You'd open it by turning the crank."

Instead of closing the closed jack-in-the-box:

say "It's closed."

Instead of opening the closed jack-in-the-box:

say "You grasp the little wooden ball and begin to turn the crank as you hold the jack-in-the-box steady. A dark little tune plinks its way out, echoing forth from the little tin box. It's not 'all around the mulberry bush' or any song you recognize, so you don[apostrophe]t quite expect it when its last note ends, and the spring-loaded doll within leaps out with surprising agility. You jump a tiny bit, in spite of yourself. The devil doll looks pleased.";

move the open jack-in-the-box to the player;

now the closed jack-in-the-box is nowhere;

[Special jack-in-the-box locations:]

if the player is in TLoUP:

say "[line break]For some reason, the crack of the jack-in-the-box opening unnerves your brother. He leaps up from the couch for a moment. 'Quit it, you craphead,' your brother snarls. He gives you an extremely intense look and lays back on the couch.";

otherwise if the player is in TLOUV:

say "[line break]'AAAAAAAGH,' the seaperson screams, leaping fully into the air, a wide, scratchy bellow. 'Goddamnit. Get that creepy thing away from me,' she requests sincerely, 'What the hell is that, a little devil-in-a-box? What's wrong with you?'.";

otherwise if the player is in TLOPCH:

say "[line break]Mister Tuxedo lets out a sharp 'Yipe!' and eyes you warily.";

otherwise if the player is in Elbow Nebula:

say "[line break]You cannot be certain, but it almost seemed like the space jellyfish veered away from the ship for a moment.";

otherwise if the player is in The Chrysocolla Cluster:

if the businessperson is unstartled:

say "[line break]The simian businessperson's eyes whip suddenly to the face of the devil doll. Its eyes widen and turn shockingly pale blue in a clearly recognizable look of total terror. Their fingers whip forward towards you involuntarily, and you suddenly feel whatever they were holding in the palm of your own hand. It is a shiny 1964 quarter. The businessperson looks briefly dismayed but merely pulls something else out of its pocket.";

now the businessperson is startled;

move the shiny 1964 quarter to the player;

otherwise:

say "[line break]The simian businessperson's eyes widen in fear for a moment, but otherwise he keeps his cool.".

[open jack in the box is a totally different object, presto]

There is an open jack-in-the-box.

Understand "jack" or "jack-in-the-box" or "jack in the box" as the open jack-in-the-box.

The description of the open jack-in-the-box is "The jack-in-the-box is a brightly painted tin cube, and actually looks to be some sort of antique. It is detailed with flames, and written on the back and front are the words 'diable en boîte'. Its tin lid is popped open, revealing a small fabric devil puppet.". The devil doll is a part of the open jack-in-the-box. The description of the devil doll is "The devil doll looks handmade, from fabric and wood. It has bright, black beads for eyes and a grinning face. It looks delighted at its recent opportunity to surprise you with its cartoonish evil.". Understand "puppet/spring/horns/doll" as the devil doll. The black bead eyes are a part of the devil doll. The description of the black bead eyes is "Glassy.". The spent hand crank is a part of the open jack-in-the-box. The description is "A wire hand crank with a small wooden ball as a handle on the end. You can turn the crank, but the jack-in-the-box is already out-of-the-box.". The open lid of the jack-in-the-box is a part of the open jack-in-the-box.

Understand "turn [the spent hand crank]" as opening.

Understand "twist [the spent hand crank]" as opening.

Instead of closing the open lid of the jack-in-the-box:

try closing the open jack-in-the-box.

Instead of opening the spent hand crank, say "You can turn the crank, but the jack-in-the-box is already out-of-the-box."

Instead of opening the open jack-in-the-box:

say "You can turn the crank, but the jack-in-the-box is already out-of-the-box."

Instead of closing the open jack-in-the-box:

say "You shove the devil doll into the body of the box, and shut the lid with a satisfying snap.";

move the closed jack-in-the-box to the player;

now the open jack-in-the-box is nowhere.

test jack-in-the-box with "f / f / f / open toy box / x jack-in-the-box / turn crank / x jack-in-the-box / close jack-in-the-box / twist crank / twist crank"

[the lite-brite]

There is a lite-brite in the toy box. It is a container. It is pluggable.

Understand "lite/brite" or "lite brite" or "light-bright" or "light bright" as the lite-brite.

The description of the lite-brite is "You're looking at a white plastic case with a black plastic pegboard covering one side. Attached to the back is a black power cord. It's got a little lightbulb inside, and usually comes with sheets of black construction paper to affix to the pegboard. Usually comes with dozens of transparent, colored pegs too. If you had them, you'd push the pegs into the pegboard to make little light-up pictures.[if the page is in the lite-brite and the lite-brite is plugged][ink-activation-text][otherwise if the page is in the lite-brite]You have the last page of the coloring book mounted in the lite-brite.[otherwise]You don't see any of that stuff though.[end if]".

The flimsy cord is a part of the lite-brite. The description is "It's a black power cord with ungrounded prongs.".

The ungrounded prongs are a part of the lite-brite. The description is "They are ungrounded."

Instead of inserting something (called the item) into the lite-brite:

if the item is the picture:

say "The picture is way too small.";

else if the item is the last page and the coloring book is torn:

if the lite-brite is plugged:

say "You slide the last page into the lite-brite, activating the glowing ink on the coloring book page.[ink-activation-text]";

if the player is in The Elbow Nebula and the jellyfish is not delighted:

now the jellyfish is delighted;

say "[line break][jellyfish-delight-text]";

otherwise:

say "You slide the last page into the lite-brite.";

now the last page is in the lite-brite;

otherwise:

say "Only a single piece of paper would slide into the lite-brite."

[coloring book]

There is a coloring book in the toy box. The description of the coloring book is "The title of the coloring book reads 'Horse Party!' Inside are drawings of horses in pastoral settings, but with festive party hats. They are doing no discernible celebrating. Seems a little demented, really. A couple of the pictures are colored neatly, and one is very carefully colored, as if by an adult.[if the coloring book is untorn]The last page is black with some kind of glow-in-the-dark ink.[end if]".

A thing can be torn or untorn. A thing is usually untorn. The coloring book is untorn.

The last page is a part of the coloring book. The printed name is "last page from the coloring book, black, and printed with some kind of glow-in-the-dark ink". The description is " [if the last page is in the lite-brite and the lite-brite is plugged][ink-activation-text][otherwise]The last page is printed on black construction paper, in some kind of barely visible ink. It looks like it must be some kind of weird glow-in-the-dark ink.[end if]".

The weird glow-in-the-dark ink is a part of the last page. The description is "[if the last page is in the lite-brite and the lite-brite is plugged]The weird glow-in-the-dark-ink has been activated somehow by the bulb, and now appears in bright, day-glo colors.[otherwise]You cup your hand over the ink, to see if it glows in the dark, but it doesn't. There must be some other way to get it to glow.[end if]". Understand "day-glo" as the ink.

Instead of taking the page:

if the coloring book is untorn:

say "You carefully tear the last page out. It's actually perforated, so you don't feel so bad.";

move the last page to the player;

now the coloring book is torn;

otherwise:

continue the action.

Understand "color [the coloring book]" as coloring. Coloring is an action applying to one visible thing.

Instead of coloring the coloring book, say "You don't have anything to color with, but you run your finger over one of the already-colored pages and pretend for a little while."

The pictures are a part of the coloring book. Understand "colors/drawings/drawing/pages/horse/horses/hat/hats/fences/barns" as the pictures. The description of the pictures is "There are several pictures of horses, and they are doing normal horse things, like standing near fences and barns. They are not partying. They are just wearing party hats. Some of them are colored, but most of them are not.".

The hats are a part of the coloring book. Understand "hat/stripe/stripes" as the hats. The description of the hats is "Every hat is an identical, stereotypical conical party hat. They are striped, and do not have any other adornment like streamers or tassels.".

[ink-activation-text]

To say ink-activation-text: say "With the lite-brite plugged in, the special ink of the last page is activated. A final horse party is depicted here, with horses in party hats like the rest of the coloring book, but brightly lit in multiple day-glo colors. One of the horses has reared up in a joyful, victorious pose."

There is a small heart shaped locket in the toy box. It is an openable closed container. It is wearable. The description is "It is a small pewter locket. It looks a bit old fashioned. [if locket is open]The locket has been opened on its tiny hinge.[otherwise]It has a small clasp on the side and looks like you could easily open it.[end if][if the picture is not in the locket and the locket is open] On the metal surface behind the picture is a tiny, engraved heart.[end if]". Understand "clasp" as the locket.

Instead of inserting something (called the item) into the locket:

if the item is not the picture:

say "The locket is quite small." instead;

otherwise:

continue the action.

There is a faded picture of a child who looks a lot like you in the locket. The description of the picture is "You don't remember ever seeing any picture of you like this photo, but this one looks almost exactly like other pictures of you at about three. There is a smile that's a mix of sadness and joy on the child's face. When you look at it, you can almost feel the feeling."

Understand "photo/photograph/smile" as the picture.

There is a small hobby horse in the toy box. The description of the horse is "It is a small, wooden hobby horse. It's very sturdily built, but made to entertain a three-year old. It has yarn for a mane." The yarn mane is a part of the horse. The description is "The mane is made from tight loops of yarn.".

test toybox with "f / f / f / open box / x doll / x hair / x breasts / bend doll / x jack-in-the-box / x lite-brite / x coloring book"

[Your Brother]

There is a couch in TLoUP. It is a supporter. It is fixed in place. The description of the couch is "This is the blue corduroy couch of your youth. You have rolled over on it many times and sat up to read its wrinkled poem on your arm. Why would anyone get a corduroy couch?"

Instead of smelling the couch, say "Smells like dust and corduroy. Also, don't smell couches, it's in general a bad idea."

The wrinkled poem is scenery in TLoUP. The description is "'Wrm allre my lv,' you remember it saying.".

Instead of reading the wrinkled poem, try examining the wrinkled poem. Reading is an action applying to one visible thing.

There is a penny. The penny can be found or lost. The penny is lost. The description of the penny is "It's a single penny, so grimy you can't read the date. It looks older than 1982, which means it's made of solid copper, but coated in rust and grime."

The printed name of the penny is "small, grimy penny from under the couch".

Instead of looking under the couch when the penny is lost:

move the penny to TLoUP;

now the penny is found;

say "There's nothing under there except a small, grimy penny."

Table 1 - TV Shows

There is a TV in TLOUP. It is fixed in place. It is a switched on device.

Instead of examining the TV:

choose a random row in the Table of TV Shows;

say "An early 35' flatscreen. Bulky, black, and plastic. It lived in your den for way too long, just because no one wanted to lift it. It's odd to see it here, in The Land of Unrealized Possibilities. It is showing '[show entry]' on channel [channel entry]."

Understand "channel/knob/television" as TV.

Understand "change [something]" as changing. Changing is an action applying to one visible thing.

To say tv-changing-text: say "[one of]'C'mon, Farts McJohnson,' your brother says, wearily, 'I[apostrophe]m watching this.'[or]'Hey, I[apostrophe]ve got an idea. Why not find literally any other way to entertain yourself.'[or]'Look, I know it's the God-given job of a little sibling to mar the TV-watching experience, but if you could give it a rest, I'd really appreciate it.'[or]'Ugh. Stop.'[stopping]".

Instead of changing a thing:

if the noun is the TV:

say tv-changing-text;

else if the noun is the player:

say "You can only change when you're ready.";

otherwise:

say "True change comes from within.".

Instead of turning the TV:

say tv-changing-text;

Instead of switching off the TV:

say tv-changing-text.

Understand "block [TV]" as blocking. Blocking is an action applying to one visible thing.

Instead of blocking the TV:

say "'Real mature,' your brother says, and cranes his neck to see around you."

your brother is a man. Brother is on the couch. The description of brother is "Your brother is a lean masterpiece of laziness and force. He is devoted to his wasting of time right now and has himself wedged into the couch like a part of it. He is watching TV, and frequently changing the channel."

Understand "bro" as brother.

The remote control is scenery in TLOUP. The description of the remote control is "Your brother is holding it, and, almost rhythmically, changing the channel."

Understand "remote/clicker" as the remote control.

Instead of taking the remote control, say "Your brother snatches the remote away from you and gives you a quick, dirty look that reminds you he's ready to back it up with the kind of painful violence that will not leave a mark."

Instead of smelling brother:

say "Weirdly, he smells fine."

Instead of attacking brother:

say "[one of]Your brother nearly-psychically determines your intention. In a flash, he socks you in the quadricep with precision and speed. He hits what you realize is an existing bruise from last time and you have to take deep breaths to keep from doubling over in pain. ‘What’s your problem, you aggro dipwad?’ he says, distractedly, eyes still on the TV.[or]Your brother has been on the planet a little longer than you, and he isn't tricked by your simple attacks. He uses a simple karate chop to the solar plexus and you have to fight the urge to barf for a moment.[stopping]";

Instead of kissing brother:

say "A swift wave of nausea dissuades you."

Understand "kick [brother]" or "tickle [brother]" as attacking.

Understand "my brother", "bro" as brother.

[special brother dialog rules]

[any visible thing]

Instead of thing-asking brother about a thing:

say "'It's [a second noun], just look at it yourself.'".

Instead of thing-asking brother about brother:

say "'Yes, I[apostrophe]m your brother. I am watching TV.'".

Instead of thing-asking brother about couch:

say "'I am the current sole resident of the couch. You can sit on the toy box. Or the floor. I do not care. You don't really need to sit.'".

Instead of thing-asking brother about locket:

say "'Yeah, I think it was mom[apostrophe]s. Because she loves you soooooo much. Barf.'".

Instead of thing-asking brother about jack-in-the-box:

say "'Can you do me a favor and play with that somewhere else? I hate its creepy little French song. And face. I hate everything about it.'".

Instead of thing-asking brother about block:

say "Your brother rolls his eyes, 'It is definitely a wooden block. See if you can get it open, I think it has gold inside.'".

Instead of thing-asking brother about lite-brite:

say "Oh yeah, you know the coloring book came with a special lite-brite bulb. If you put the last page in it and plug it in, the picture glows.'".

Instead of thing-asking brother about coloring book: say "'Yeah, it came with a special bulb for the lite-brite. I put the bulb in a long time ago. Horse party dude!'";

Instead of thing-asking brother about the player:

say "'Fun fact about you: you are mentally challenged.'".

Instead of thing-telling brother about a thing:

say "'Yeah, it's [the second noun], snotball, what do you want from me?'".

[specific non-visible thing topics - asking]

Instead of asking your brother about "quarter/quarters":

say "'I don[apostrophe]t have a quarter, no, but I think there's a penny under the couch.'".

Instead of asking your brother about "mister/tuxedo":

say "'Aw yeah, Mister Tuxedo is adorable.'".

Instead of asking your brother about "mister tuxedo":

say "'Aw yeah, Mister Tuxedo is adorable.'".

[specific non-visible thing topics - telling]

Instead of telling your brother about "rocket":

say "'You expect me to believe you saw a real rocket?'".

[fallthrough]

Instead of asking brother about something:

say "'What are you talking about, dogbreath?'".

Instead of telling brother about something:

say "You really like making mouth noises while I watch TV, don[apostrophe]t you?".

test brotalk with "f / f / f / ask brother about box / ask brother about jack-in-the-box / tell brother about box / tell brother about jack-in-the-box / open box / ask brother about jack / tell brother about jack / ask brother about rocket / tell brother about rocket / ask brother about quarter".

test askbro with "f / f / f / ask brother about box / ask brother about rocket / ask brother about quarter / ask brother about brother".

[Riding (the horse)]

Understand "ride [something]" as riding. Riding is an action applying to one thing.

Carry out riding:

say "You can't ride stuff like that, silly."

Instead of riding the horse:

If the horse is in the box:

say "The hobby horse takes up most of the box, and doesn't allow a lot of room to ride it.";

otherwise if the player is holding the horse:

say "You're holding the hobby horse in both of your hands. Anyone would be impressed if you found a way to ride it right now.";

otherwise:

say "You were pretty sure it was going to be awkward to do this, and it sure is. Your legs are splayed way out and the hobby horse creaks dangerously under your weight. It holds solid though, and you creak your way back and forward a few times. You can say you did it.";

Instead of riding brother, say "The mental picture is pretty funny, but you are 100% certain your brother is not going to find it funny."

Instead of entering or riding the couch, say "Your brother is utilizing so much of the couch, you don't see a good place to sit without pissing him off.".